// Dieses Povraydokument, soll eine Facettenoberfläche darstellen
// Dazu muss der Facettennormalenvektor angegeben werden:

#declare fac= < 0.5, 1.5, 1.5 >

// Ein wert der das Vielfache um das der Betrachter von der Facettenoberfläche
// entfernt ist angibt

#declare vfactor=3

// und eine Border die die Anzahl der untersuchten Kugeln festlegt
// Vorsicht bei der Wahl, die untersuchte Kugelanzahl ist die dritte Potenz!

#declare fccborder=8


  #include "colors.inc"

  background { color Cyan }

  camera {
    location vfactor*<fac.x,fac.y, fac.z>
    look_at  <0, 0,  0>
  }

  light_source { <vfactor*fac.x+1,vfactor*fac.y+1,vfactor*fac.z+1> color White}


#declare xfcc = -fccborder 

#while (xfcc < fccborder)
  #declare yfcc=-fccborder
  #while (yfcc < fccborder)
    #declare zfcc=-fccborder
    #while (zfcc < fccborder)

      #declare col = fac.x*(xfcc+yfcc)+fac.y*(xfcc+zfcc)+fac.z*(yfcc+zfcc)
      #if (col < 1)

        sphere{
          <xfcc+yfcc, xfcc+zfcc, yfcc+zfcc> , .707107
          texture {
            #switch (col)
             #case(0)
              pigment { color Red }
             #break
             #case(-1)
              pigment { color Green }
             #break
             #case(-2)
              pigment { color Blue }
             #break
             #case(-3)
              pigment { color Yellow }
             #break
             #case(-4)
              pigment { color Cyan }
             #break
             #case(-5)
              pigment { color Magenta }
             #break
             #case(-6)
              pigment { color Black }
             #break
             #case(-7)
              pigment { color Brown }
             #break
             #case(-8)
              pigment { color Pink }
             #break
            #else
              pigment { color White }
            #end
          }
        }
      #end
    #declare zfcc=zfcc+1
    #end
  #declare yfcc=yfcc+1
  #end
#declare xfcc=xfcc+1
#end